30 Excel funkcija za 30 dana: MATCH

Jučer na maratonu 30 Excel funkcija za 30 dana pronašli smo tekstualne nizove koristeći funkciju TRAŽI (TRAŽI) i također se koristi IFERROR (IFGREŠKA) i ISNUMBER (ISNUMBER) u situacijama kada funkcija daje grešku.

19. dana našeg maratona proučavat ćemo funkciju MATCH (TRAŽI). Traži vrijednost u nizu i, ako je pronađena, vraća njenu poziciju.

Dakle, okrenimo se referentnim informacijama o funkciji MATCH (MAČ) i pogledajte nekoliko primjera. Ako imate svoje primjere ili pristupe za rad s ovom funkcijom, podijelite ih u komentarima.

Funkcija 19: MATCH

funkcija MATCH (MATCH) vraća poziciju vrijednosti u nizu ili grešku #AT (#N/A) ako nije pronađen. Niz može biti sortiran ili nesortiran. Funkcija MATCH (MATCH) ne razlikuje velika i mala slova.

Kako možete koristiti funkciju MATCH?

funkcija MATCH (MATCH) vraća poziciju elementa u nizu, a ovaj rezultat mogu koristiti druge funkcije kao što su INDEX (INDEX) ili VLOOKUP (VPR). Na primjer:

  • Pronađite poziciju elementa u nesortiranoj listi.
  • Upotreba sa IZABERITE (SELECT) da konvertujete učinak učenika u slovne ocjene.
  • Upotreba sa VLOOKUP (VLOOKUP) za fleksibilan izbor kolona.
  • Upotreba sa INDEX (INDEX) za pronalaženje najbliže vrijednosti.

Sintaksa MATCH

funkcija MATCH (MATCH) ima sljedeću sintaksu:

MATCH(lookup_value,lookup_array,[match_type])

ПОИСКПОЗ(искомое_значение;просматриваемый_массив;[тип_сопоставления])

  • lookup_value (lookup_value) – Može biti tekst, broj ili logički.
  • lookup_array (lookup_array) – niz ili referenca niza (susedne ćelije u istoj koloni ili istom redu).
  • match_type (match_type) može uzeti tri vrijednosti: -1, 0 or 1. Ako je argument izostavljen, on je ekvivalentan 1.

Zamke MATCH (MATCH)

funkcija MATCH (MATCH) vraća poziciju pronađenog elementa, ali ne i njegovu vrijednost. Ako želite vratiti vrijednost, koristite MATCH (MACH) zajedno sa funkcijom INDEX (INDEX).

Primjer 1: Pronalaženje elementa u nesortiranoj listi

Za nesortiranu listu možete koristiti 0 kao vrijednost argumenta match_type (match_type) za traženje tačnog podudaranja. Ako želite pronaći točno podudaranje tekstualnog niza, možete koristiti zamjenske znakove u vrijednosti pretraživanja.

U sljedećem primjeru, da bismo pronašli poziciju mjeseca na listi, možemo napisati naziv mjeseca, bilo u cijelosti ili djelomično, koristeći zamjenske znakove.

=MATCH(D2,B3:B7,0)

=ПОИСКПОЗ(D2;B3:B7;0)

30 Excel funkcija za 30 dana: MATCH

Kao argument lookup_array (lookup_array) možete koristiti niz konstanti. U sljedećem primjeru, željeni mjesec se upisuje u ćeliju D5, a nazivi mjeseci zamjenjuju se kao drugi argument funkcije MATCH (MACH) kao niz konstanti. Ako unesete kasniji mjesec u ćeliju D5, npr. oktobar (oktobar), tada će rezultat funkcije biti #AT (#N / A).

=MATCH(D5,{"Jan","Feb","Mar"},0)

=ПОИСКПОЗ(D5;{"Jan";"Feb";"Mar"};0)

30 Excel funkcija za 30 dana: MATCH

Primjer 2: Promijenite ocjene učenika iz postotaka u slova

Pomoću funkcije možete konvertovati ocjene učenika u sistem slova MATCH (MAČ) baš kao što ste uradili sa VLOOKUP (VPR). U ovom primjeru, funkcija se koristi u sprezi sa IZABERITE (CHOICE), koji vraća procjenu koja nam je potrebna. Argument match_type (match_type) je postavljeno jednako -1, jer su rezultati u tabeli sortirani u opadajućem redosledu.

Kada argument match_type (tip_podudaranja) je -1, rezultat je najmanja vrijednost koja je veća ili ekvivalentna željenoj vrijednosti. U našem primjeru, željena vrijednost je 54. Pošto takva vrijednost ne postoji na listi rezultata, vraća se element koji odgovara vrijednosti 60. Pošto je 60 na četvrtom mjestu na listi, rezultat funkcije IZABERITE (SELECT) će biti vrijednost koja se nalazi na 4. poziciji, odnosno ćeliji C6, koja sadrži skor D.

=CHOOSE(MATCH(B9,B3:B7,-1),C3,C4,C5,C6,C7)

=ВЫБОР(ПОИСКПОЗ(B9;B3:B7;-1);C3;C4;C5;C6;C7)

30 Excel funkcija za 30 dana: MATCH

Primjer 3: Kreirajte fleksibilan izbor stupaca za VLOOKUP (VLOOKUP)

Da biste dali više fleksibilnosti funkciji VLOOKUP (VLOOKUP) Možete koristiti MATCH (MATCH) za pronalaženje broja stupca, umjesto da čvrsto kodira njegovu vrijednost u funkciju. U sljedećem primjeru, korisnici mogu odabrati regiju u ćeliji H1, to je vrijednost koju traže VLOOKUP (VPR). Zatim mogu odabrati mjesec u ćeliji H2 i funkciju MATCH (MATCH) će vratiti broj kolone koji odgovara tom mjesecu.

=VLOOKUP(H1,$B$2:$E$5,MATCH(H2,B1:E1,0),FALSE)

=ВПР(H1;$B$2:$E$5;ПОИСКПОЗ(H2;B1:E1;0);ЛОЖЬ)

30 Excel funkcija za 30 dana: MATCH

Primjer 4: Pronalaženje najbliže vrijednosti pomoću INDEX (INDEX)

funkcija MATCH (MATCH) odlično radi u kombinaciji s funkcijom INDEX (INDEX), koji ćemo detaljnije pogledati malo kasnije u ovom maratonu. U ovom primjeru, funkcija MATCH (MATCH) se koristi za pronalaženje najbližeg tačnom broju od nekoliko pogodjenih brojeva.

  1. funkcija ABS vraća modul razlike između svakog pogodjenog i tačnog broja.
  2. funkcija MIN (MIN) pronalazi najmanju razliku.
  3. funkcija MATCH (MATCH) pronalazi adresu najmanje razlike u listi razlika. Ako postoji više odgovarajućih vrijednosti na listi, prva će biti vraćena.
  4. funkcija INDEX (INDEX) vraća ime koje odgovara ovoj poziciji sa liste imena.

=INDEX(B2:B5,MATCH(MIN(ABS(C2:C5-F1)),ABS(C2:C5-F1),0))

=ИНДЕКС(B2:B5;ПОИСКПОЗ(МИН(ABS(C2:C5-F1));ABS(C2:C5-F1);0))

30 Excel funkcija za 30 dana: MATCH

Ostavite odgovor